如何在曲线坐标系下进行向量演算¶
本教程将介绍SageMath在三维欧几里得空间中的一些向量演算功能。相应的工具已经通过 SageManifolds 项目。
The tutorial is also available as a Jupyter notebook, either
passive (nbviewer)
or interactive (binder).
使用球坐标¶
使用球坐标的步骤 (r,theta,phi) 在欧几里德3空间内 mathbb{{E}}^3 ，用关键字声明后者就足够了 coordinates='spherical' ：：
sage: E.<r,th,ph> = EuclideanSpace(coordinates='spherical')
sage: E
Euclidean space E^3
多亏了注释 <r,th,ph> 在上述声明中，坐标 (r,theta,phi) 立即可用作三个符号变量 r ， th 和 ph （无需通过 var() ，即键入 r, th, ph = var('r th ph') ）：
sage: r is E.spherical_coordinates()[1]
True
sage: (r, th, ph) == E.spherical_coordinates()[:]
True
sage: type(r)
<type 'sage.symbolic.expression.Expression'>
此外，坐标 Latex 符号已经设置：
sage: latex(th)
{\theta}
坐标范围为：
sage: E.spherical_coordinates().coord_range()
r: (0, +oo); th: (0, pi); ph: [0, 2*pi] (periodic)
mathbb{{E}}^3 被赋予 正交 矢量帧 (e_r, e_theta, e_phi) 与球坐标相关：
sage: E.frames()
[Coordinate frame (E^3, (d/dr,d/dth,d/dph)),
Vector frame (E^3, (e_r,e_th,e_ph))]
在上述输出中， (d/dr,d/dth,d/dph) = left(frac{{partial}}{{partial r}}, frac{{partial}}{{partialtheta}}, frac{{partial}}{{partial phi}}right) 是 坐标 与关联的帧 (r,theta,phi) ；它不是正交框架，在下面也不会使用。默认帧为正交帧：
sage: E.default_frame()
Vector frame (E^3, (e_r,e_th,e_ph))
定义向量场¶
我们定义一个向量场 mathbb{{E}}^3 从它在正交向量框架中的分量 (e_r,e_theta,e_phi) ：：
sage: v = E.vector_field(r*sin(2*ph)*sin(th)^2 + r,
....: r*sin(2*ph)*sin(th)*cos(th),
....: 2*r*cos(ph)^2*sin(th), name='v')
sage: v.display()
v = (r*sin(2*ph)*sin(th)^2 + r) e_r + r*cos(th)*sin(2*ph)*sin(th) e_th
+ 2*r*cos(ph)^2*sin(th) e_ph
我们可以访问 v 通过方括号运算符：
sage: v[1]
r*sin(2*ph)*sin(th)^2 + r
sage: v[:]
[r*sin(2*ph)*sin(th)^2 + r, r*cos(th)*sin(2*ph)*sin(th), 2*r*cos(ph)^2*sin(th)]
向量场可以在 mathbb{{E}}^3 ：：
sage: p = E((1, pi/2, pi), name='p')
sage: p
Point p on the Euclidean space E^3
sage: p.coordinates()
(1, 1/2*pi, pi)
sage: vp = v.at(p)
sage: vp
Vector v at Point p on the Euclidean space E^3
sage: vp.display()
v = e_r + 2 e_ph
我们可以用一般分量定义向量场：
sage: u = E.vector_field(function('u_r')(r,th,ph),
....: function('u_theta')(r,th,ph),
....: function('u_phi')(r,th,ph),
....: name='u')
sage: u.display()
u = u_r(r, th, ph) e_r + u_theta(r, th, ph) e_th + u_phi(r, th, ph) e_ph
sage: u[:]
[u_r(r, th, ph), u_theta(r, th, ph), u_phi(r, th, ph)]
它在这一点上的价值 p 然后是：
sage: up = u.at(p)
sage: up.display()
u = u_r(1, 1/2*pi, pi) e_r + u_theta(1, 1/2*pi, pi) e_th
+ u_phi(1, 1/2*pi, pi) e_ph
球坐标系中的微分算子¶
标准操作员 mathrm{{grad}} ， mathrm{{div}} ， mathrm{{curl}} 向量演算中涉及到的方法可以作为标量场和向量场上的方法（例如。 v.div() ). 但是，考虑到标准的数学符号（例如。 div(v) )，让我们导入函数 grad() ， div() ， curl() 和 laplacian() ：：
sage: from sage.manifolds.operators import *
梯度¶
我们首先引入标量场，通过它在笛卡尔坐标下的表达式；在这个例子中，我们考虑 (r,theta,phi) ：：
sage: F = E.scalar_field(function('f')(r,th,ph), name='F')
sage: F.display()
F: E^3 --> R
(r, th, ph) |--> f(r, th, ph)
价值 F 在某一点上：
sage: F(p)
f(1, 1/2*pi, pi)
坡度 F ：：
sage: grad(F)
Vector field grad(F) on the Euclidean space E^3
sage: grad(F).display()
grad(F) = d(f)/dr e_r + d(f)/dth/r e_th + d(f)/dph/(r*sin(th)) e_ph
sage: norm(grad(F)).display()
|grad(F)|: E^3 --> R
(r, th, ph) |--> sqrt((r^2*(d(f)/dr)^2 + (d(f)/dth)^2)*sin(th)^2
+ (d(f)/dph)^2)/(r*sin(th))
发散¶
向量场的散度：
sage: s = div(u)
sage: s.display()
div(u): E^3 --> R
(r, th, ph) |--> ((r*d(u_r)/dr + 2*u_r(r, th, ph)
+ d(u_theta)/dth)*sin(th) + cos(th)*u_theta(r, th, ph)
+ d(u_phi)/dph)/(r*sin(th))
sage: s.expr().expand()
2*u_r(r, th, ph)/r + cos(th)*u_theta(r, th, ph)/(r*sin(th))
+ diff(u_theta(r, th, ph), th)/r + diff(u_phi(r, th, ph), ph)/(r*sin(th))
+ diff(u_r(r, th, ph), r)
为了 v ，我们有：
sage: div(v).expr()
3
卷曲¶
向量场的旋度：
sage: s = curl(u)
sage: s
Vector field curl(u) on the Euclidean space E^3
sage: s.display()
curl(u) = (cos(th)*u_phi(r, th, ph) + sin(th)*d(u_phi)/dth
- d(u_theta)/dph)/(r*sin(th)) e_r - ((r*d(u_phi)/dr + u_phi(r, th, ph))*sin(th)
- d(u_r)/dph)/(r*sin(th)) e_th + (r*d(u_theta)/dr + u_theta(r, th, ph)
- d(u_r)/dth)/r e_ph
为了 v ，我们有：
sage: curl(v).display()
curl(v) = 2*cos(th) e_r - 2*sin(th) e_th
梯度的旋度总是为零：
sage: curl(grad(F)).display()
curl(grad(F)) = 0
旋度的散度总是零：
sage: div(curl(u)).display()
div(curl(u)): E^3 --> R
(r, th, ph) |--> 0
拉普拉斯¶
标量场的拉普拉斯：
sage: s = laplacian(F)
sage: s.display()
Delta(F): E^3 --> R
(r, th, ph) |--> ((r^2*d^2(f)/dr^2 + 2*r*d(f)/dr
+ d^2(f)/dth^2)*sin(th)^2 + cos(th)*sin(th)*d(f)/dth
+ d^2(f)/dph^2)/(r^2*sin(th)^2)
sage: s.expr().expand()
2*diff(f(r, th, ph), r)/r + cos(th)*diff(f(r, th, ph), th)/(r^2*sin(th))
+ diff(f(r, th, ph), th, th)/r^2 + diff(f(r, th, ph), ph, ph)/(r^2*sin(th)^2)
+ diff(f(r, th, ph), r, r)
向量场的拉普拉斯算子：
sage: Du = laplacian(u)
sage: Du.display()
Delta(u) = ((r^2*d^2(u_r)/dr^2 + 2*r*d(u_r)/dr - 2*u_r(r, th, ph)
+ d^2(u_r)/dth^2 - 2*d(u_theta)/dth)*sin(th)^2 - ((2*u_theta(r, th, ph)
- d(u_r)/dth)*cos(th) + 2*d(u_phi)/dph)*sin(th) + d^2(u_r)/dph^2)/(r^2*sin(th)^2) e_r
+ ((r^2*d^2(u_theta)/dr^2 + 2*r*d(u_theta)/dr + 2*d(u_r)/dth + d^2(u_theta)/dth^2)*sin(th)^2
+ cos(th)*sin(th)*d(u_theta)/dth - 2*cos(th)*d(u_phi)/dph - u_theta(r, th, ph)
+ d^2(u_theta)/dph^2)/(r^2*sin(th)^2) e_th
+ ((r^2*d^2(u_phi)/dr^2 + 2*r*d(u_phi)/dr
+ d^2(u_phi)/dth^2)*sin(th)^2 + (cos(th)*d(u_phi)/dth + 2*d(u_r)/dph)*sin(th)
+ 2*cos(th)*d(u_theta)/dph - u_phi(r, th, ph) + d^2(u_phi)/dph^2)/(r^2*sin(th)^2) e_ph
因为这个表达式很长，我们可能会要求按组件显示组件：
sage: Du.display_comp()
Delta(u)^1 = ((r^2*d^2(u_r)/dr^2 + 2*r*d(u_r)/dr - 2*u_r(r, th, ph) + d^2(u_r)/dth^2
- 2*d(u_theta)/dth)*sin(th)^2 - ((2*u_theta(r, th, ph) - d(u_r)/dth)*cos(th)
+ 2*d(u_phi)/dph)*sin(th) + d^2(u_r)/dph^2)/(r^2*sin(th)^2)
Delta(u)^2 = ((r^2*d^2(u_theta)/dr^2 + 2*r*d(u_theta)/dr + 2*d(u_r)/dth
+ d^2(u_theta)/dth^2)*sin(th)^2 + cos(th)*sin(th)*d(u_theta)/dth
- 2*cos(th)*d(u_phi)/dph - u_theta(r, th, ph) + d^2(u_theta)/dph^2)/(r^2*sin(th)^2)
Delta(u)^3 = ((r^2*d^2(u_phi)/dr^2 + 2*r*d(u_phi)/dr + d^2(u_phi)/dth^2)*sin(th)^2
+ (cos(th)*d(u_phi)/dth + 2*d(u_r)/dph)*sin(th) + 2*cos(th)*d(u_theta)/dph
- u_phi(r, th, ph) + d^2(u_phi)/dph^2)/(r^2*sin(th)^2)
我们可以扩展每个组件：
sage: for i in E.irange():
....: s = Du[i].expand()
sage: Du.display_comp()
Delta(u)^1 = 2*d(u_r)/dr/r - 2*u_r(r, th, ph)/r^2
- 2*cos(th)*u_theta(r, th, ph)/(r^2*sin(th)) + cos(th)*d(u_r)/dth/(r^2*sin(th))
+ d^2(u_r)/dth^2/r^2 - 2*d(u_theta)/dth/r^2 - 2*d(u_phi)/dph/(r^2*sin(th))
+ d^2(u_r)/dph^2/(r^2*sin(th)^2) + d^2(u_r)/dr^2
Delta(u)^2 = 2*d(u_theta)/dr/r + 2*d(u_r)/dth/r^2 + cos(th)*d(u_theta)/dth/(r^2*sin(th))
+ d^2(u_theta)/dth^2/r^2 - 2*cos(th)*d(u_phi)/dph/(r^2*sin(th)^2)
- u_theta(r, th, ph)/(r^2*sin(th)^2) + d^2(u_theta)/dph^2/(r^2*sin(th)^2)
+ d^2(u_theta)/dr^2
Delta(u)^3 = 2*d(u_phi)/dr/r + cos(th)*d(u_phi)/dth/(r^2*sin(th))
+ d^2(u_phi)/dth^2/r^2 + 2*d(u_r)/dph/(r^2*sin(th))
+ 2*cos(th)*d(u_theta)/dph/(r^2*sin(th)^2) - u_phi(r, th, ph)/(r^2*sin(th)^2)
+ d^2(u_phi)/dph^2/(r^2*sin(th)^2) + d^2(u_phi)/dr^2
作为测试，我们可以检查这些公式是否与维基百科文章中的公式一致 Del in cylindrical and spherical coordinates .
使用柱坐标¶
柱坐标的使用 (rho,phi,z) 在欧几里得空间里 mathbb{{E}}^3 与球坐标的基础相同。首先，你只需声明：
sage: E.<rh,ph,z> = EuclideanSpace(coordinates='cylindrical')
坐标范围为：
sage: E.cylindrical_coordinates().coord_range()
rh: (0, +oo); ph: [0, 2*pi] (periodic); z: (-oo, +oo)
默认的矢量帧是正交帧 (e_rho,e_phi,e_z) 与柱坐标相关：
sage: E.default_frame()
Vector frame (E^3, (e_rh,e_ph,e_z))
我们可以从向量场的分量中定义向量场：
sage: v = E.vector_field(rh*(1+sin(2*ph)), 2*rh*cos(ph)^2, z,
....: name='v')
sage: v.display()
v = rh*(sin(2*ph) + 1) e_rh + 2*rh*cos(ph)^2 e_ph + z e_z
sage: v[:]
[rh*(sin(2*ph) + 1), 2*rh*cos(ph)^2, z]
sage: u = E.vector_field(function('u_rho')(rh,ph,z),
....: function('u_phi')(rh,ph,z),
....: function('u_z')(rh,ph,z),
....: name='u')
sage: u.display()
u = u_rho(rh, ph, z) e_rh + u_phi(rh, ph, z) e_ph + u_z(rh, ph, z) e_z
sage: u[:]
[u_rho(rh, ph, z), u_phi(rh, ph, z), u_z(rh, ph, z)]
柱坐标系中的微分算子¶
sage: from sage.manifolds.operators import *
坡度：
sage: F = E.scalar_field(function('f')(rh,ph,z), name='F')
sage: F.display()
F: E^3 --> R
(rh, ph, z) |--> f(rh, ph, z)
sage: grad(F)
Vector field grad(F) on the Euclidean space E^3
sage: grad(F).display()
grad(F) = d(f)/drh e_rh + d(f)/dph/rh e_ph + d(f)/dz e_z
分歧：
sage: s = div(u)
sage: s.display()
div(u): E^3 --> R
(rh, ph, z) |--> (rh*d(u_rho)/drh + rh*d(u_z)/dz + u_rho(rh, ph, z) + d(u_phi)/dph)/rh
sage: s.expr().expand()
u_rho(rh, ph, z)/rh + diff(u_phi(rh, ph, z), ph)/rh + diff(u_rho(rh, ph, z), rh)
+ diff(u_z(rh, ph, z), z)
卷曲：
sage: s = curl(u)
sage: s
Vector field curl(u) on the Euclidean space E^3
sage: s.display()
curl(u) = -(rh*d(u_phi)/dz - d(u_z)/dph)/rh e_rh + (d(u_rho)/dz - d(u_z)/drh) e_ph
+ (rh*d(u_phi)/drh + u_phi(rh, ph, z) - d(u_rho)/dph)/rh e_z
标量场的拉普拉斯：
sage: s = laplacian(F)
sage: s.display()
Delta(F): E^3 --> R
(rh, ph, z) |--> (rh^2*d^2(f)/drh^2 + rh^2*d^2(f)/dz^2 + rh*d(f)/drh
+ d^2(f)/dph^2)/rh^2
sage: s.expr().expand()
diff(f(rh, ph, z), rh)/rh + diff(f(rh, ph, z), ph, ph)/rh^2
+ diff(f(rh, ph, z), rh, rh) + diff(f(rh, ph, z), z, z)
向量场的拉普拉斯算子：
sage: Du = laplacian(u)
sage: Du.display()
Delta(u) = (rh^2*d^2(u_rho)/drh^2 + rh^2*d^2(u_rho)/dz^2 + rh*d(u_rho)/drh
- u_rho(rh, ph, z) - 2*d(u_phi)/dph + d^2(u_rho)/dph^2)/rh^2 e_rh
+ (rh^2*d^2(u_phi)/drh^2 + rh^2*d^2(u_phi)/dz^2 + rh*d(u_phi)/drh
- u_phi(rh, ph, z) + d^2(u_phi)/dph^2 + 2*d(u_rho)/dph)/rh^2 e_ph
+ (rh^2*d^2(u_z)/drh^2 + rh^2*d^2(u_z)/dz^2 + rh*d(u_z)/drh
+ d^2(u_z)/dph^2)/rh^2 e_z
sage: for i in E.irange():
....: s = Du[i].expand()
sage: Du.display_comp()
Delta(u)^1 = d(u_rho)/drh/rh - u_rho(rh, ph, z)/rh^2 - 2*d(u_phi)/dph/rh^2
+ d^2(u_rho)/dph^2/rh^2 + d^2(u_rho)/drh^2 + d^2(u_rho)/dz^2
Delta(u)^2 = d(u_phi)/drh/rh - u_phi(rh, ph, z)/rh^2 + d^2(u_phi)/dph^2/rh^2
+ 2*d(u_rho)/dph/rh^2 + d^2(u_phi)/drh^2 + d^2(u_phi)/dz^2
Delta(u)^3 = d(u_z)/drh/rh + d^2(u_z)/dph^2/rh^2 + d^2(u_z)/drh^2 + d^2(u_z)/dz^2
再次，我们可以检查以上公式是否与维基百科文章中的公式一致 Del in cylindrical and spherical coordinates .